Windows 10 Ürün Anahtarı Nasıl Bulunur?

Windows 10 Ürün Anahtarı Nasıl Bulunur?

Windows 10 ürün anahtarı nasıl bulunur? Bilgisayarınızda yüklü olan Windows’un ürün anahtarını programsız ve küçük ücretsiz programlar ile bulabilirsiniz. Bu makalemizde Windows ürün anahtarını programsız bulma yöntemlerini anlatacağız.

Windows 10 ürün anahtarını;

• Komut isteminden (CMD)
• PowerShell komut satırı uygulamasından
• Küçük bir Vbscript ile programsız öğrenebilirsiniz.

Ürün Anahtarını Komut İstemi (CMD) ile Öğrenme

Ürün anahtarını komut istemi (CMD) ile öğrenme:

Başlat menüsünde veya arma çubuğunda CMD yazın ve arama sonuçlarında komut istemini yönetici olarak çalıştır seçeneğine tıklayın. Ardından;

Aşağıdaki komutu kopyalayıp komut satırına yapıştırın ve enter tuşuna basın.

wmic path softwarelicensingservice get OA3xOriginalProductKey

Komutu çalıştırdığınızda OA3xOriginalProductKey altında Windows 10 ürün anahtarınızı görüntüleyebilirsiniz.

PowerShell ile Windows 10 Ürün Anahtarı Bulma

PowerShell komutları ile Windows ürün anahtarı öğrenme:

Başlat menüsünde veya arma çubuğunda PowerShell yazın ve arama sonuçlarında Run as Administrator (yönetici olarak çalıştır) seçeneğine tıklayın. Ardından;

Aşağıdaki komutu kopyalayıp PowerShell komut satırına yapıştırın ve enter tuşuna basın.

(Get-WmiObject -query 'select * from SoftwareLicensingService').OA3xOriginalProductKey

Komutu çalıştırdığınızda Windows 10 ürün anahtarınızı görüntüleyebilirsiniz.

Not: Yukarıdaki iki sorguda bilgisayarınızın UEFI/BIOS ‘unda depolanan ürün anahtarını verir. Özellikle Windows 8’den sonra ürün anahtarı çoğu bilgisayarlara yerleşik olarak yüklenmeye başlandı. Eğer ürün anahtar sonucu boş gelir ise bilgisayarınızda ürün anahtarı yerleşik olarak yüklü değil demektir. Fakat bu gibi durumlarda aşağıdaki Vbscript kodunu deneyebilirsiniz. Bu VBscript kodu kayıt defterindeki ürün anahtarını bulmanızı sağlar.

Vbscript ile Windows 10 Ürün Anahtarı Bulma

Aşağıdaki kodu kopyalayın ve yeni bir Not Defteri açıp yapıştırın. Ardından dosya adını .vbs uzantılı olacak şekilde değiştirin. Örnek ürünanahtarı.vbs, product.vbs gibi bir ad verin. Daha sonra;

Option Explicit  
 
Dim objshell,path,DigitalID, Result  
Set objshell = CreateObject("WScript.Shell") 
'Set registry key path 
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\" 
'Registry key value 
DigitalID = objshell.RegRead(Path & "DigitalProductId") 
Dim ProductName,ProductID,ProductKey,ProductData 
'Get ProductName, ProductID, ProductKey 
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName") 
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID") 
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)  
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey 
'Show messbox if save to a file  
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then 
   Save ProductData  
End If 
 
 
 
'Convert binary to chars 
Function ConvertToKey(Key) 
    Const KeyOffset = 52 
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert 
    'Check if OS is Windows 8 
    isWin8 = (Key(66) \ 6) And 1 
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4) 
    i = 24 
    Maps = "BCDFGHJKMPQRTVWXY2346789" 
    Do 
           Current= 0 
        j = 14 
        Do 
           Current = Current* 256 
           Current = Key(j + KeyOffset) + Current 
           Key(j + KeyOffset) = (Current \ 24) 
           Current=Current Mod 24 
            j = j -1 
        Loop While j >= 0 
        i = i -1 
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput 
        Last = Current 
    Loop While i >= 0  
     
    If (isWin8 = 1) Then 
        keypart1 = Mid(KeyOutput, 2, Last) 
        insert = "N" 
        KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0) 
        If Last = 0 Then KeyOutput = insert & KeyOutput 
    End If     
     
 
    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5) 
    
     
End Function 
'Save data to a file 
Function Save(Data) 
    Dim fso, fName, txt,objshell,UserName 
    Set objshell = CreateObject("wscript.shell") 
    'Get current user name  
    UserName = objshell.ExpandEnvironmentStrings("%UserName%")  
    'Create a text file on desktop  
    fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt" 
    Set fso = CreateObject("Scripting.FileSystemObject") 
    Set txt = fso.CreateTextFile(fName) 
    txt.Writeline Data 
    txt.Close 
End Function

Dosya uzantısını değiştirdiğinizde;

Resim 5’teki gibi script kodu dosyasına dönüşmelidir. Ardından komut dosyasını çalıştırın.

Komut dosyası çalıştığında Windows ürün anahtarınızı öğrenebilirsiniz.

Diğer konular;

• Windows’ta Yazıcıları Yedekleme ve Geri Yükleme
• Instagram Karanlık Mod Nasıl Etkinleştirilir?
• Windows 0x0000011b Hatası Nasıl Düzeltilir
• Windows 10’da Fare İmlecini İçeren Ekran Görüntüsü Almak